Om du har programmerarbakgrund så är det frågan om veckor, som Sodjan sade. Poängen är inte att lära sig assembler per se, utan att lära sig hur en PIC fungerar. Att programmera PIC är så maskinnära du kan komma. Problemet är att du döljer stora delar av PICens arkitektur om du programmerar i C eller BASIC. Programmerar du I assembler så ser du bättre hur PICen fungerar.Varför lära sig assembler i 6-12 mån om man ändå tänkt gå vidare till C senare?
Kod: Markera allt
#include <p16F690.inc>
__config (_INTRC_OSC_NOCLKOUT & _WDT_OFF & _PWRTE_OFF & _MCLRE_OFF & _CP_OFF & _BOR_OFF & _IESO_OFF & _FCMEN_OFF)
cblock 0x20
Delay1 ; Assign an address to label Delay1
Delay2
Display ; define a variable to hold the diplay
Direction
LookingFor
endc
org 0
Start:
bsf STATUS,RP0 ; select Register Page 1
movlw 0xFF
movwf TRISA ; Make PortA all input
clrf TRISC ; Make PortC all output
movlw 0x10 ; A2D Clock Fosc/8
movwf ADCON1
; bcf STATUS,RP0 ; back to Register Page 0
bcf STATUS,RP0 ; address Register Page 2
bsf STATUS,RP1
movlw 0xF7 ; we want all Port A pins Analog, except RA3
movwf ANSEL
bcf STATUS,RP0 ; address Register Page 0
bcf STATUS,RP1
movlw 0x01
movwf ADCON0 ; configure A2D for Channel 0 (RA0), Left justified, and turn on the A2D module
movlw 0x08
movwf Display
clrf Direction
clrf LookingFor ; Looking for a 0 on the button
MainLoop:
movf Display,w ; Copy the display to the LEDs
movwf PORTC
nop ; wait 5uS for A2D amp to settle and capacitor to charge.
nop ; wait 1uS
nop ; wait 1uS
nop ; wait 1uS
nop ; wait 1uS
bsf ADCON0,GO ; start conversion
btfss ADCON0,GO ; this bit will change to zero when the conversion is complete
goto $-1
movf ADRESH,w ; Copy the display to the LEDs
movwf Delay2
A2DDelayLoop:
incfsz Delay1,f ; Waste time.
goto A2DDelayLoop ; The Inner loop takes 3 instructions per loop * 256 loopss = 768 instructions
incfsz Delay2,f ; The outer loop takes and additional 3 instructions per lap * 256 loops
goto A2DDelayLoop ; (768+3) * 256 = 197376 instructions / 1M instructions per second = 0.197 sec.
; call it a two-tenths of a second.
movlw .13 ; Delay another 10mS plus whatever was above
movwf Delay2
TenmSdelay:
decfsz Delay1,f
goto TenmSdelay
decfsz Delay2,f
goto TenmSdelay
btfsc LookingFor,0
goto LookingFor1
LookingFor0:
btfsc PORTA,3 ; is the switch pressed (0)
goto Rotate
bsf LookingFor,0 ; yes Next we'll be looking for a 1
movlw 0xFF ; load the W register incase we need it
xorwf Direction,f ; yes, flip the direction bit
goto Rotate
LookingFor1:
btfsc PORTA,3 ; is the switch pressed (0)
bcf LookingFor,0
Rotate:
bcf STATUS,C ; ensure the carry bit is clear
btfss Direction,0
goto RotateLeft
RotateRight:
rrf Display,f
btfsc STATUS,C ; Did the bit rotate into the carry?
bsf Display,3 ; yes, put it into bit 3.
goto MainLoop
RotateLeft:
rlf Display,f
btfsc Display,4 ; did it rotate out of the display
bsf Display,0 ; yes, put it into bit 0
goto MainLoop
end
