Svenska ElektronikForumet

Kod: Markera allt

#include <Wire.h>
#include "RTClib.h"
RTC_DS1307 RTC;

const int digits = 4;                        // How many digits are in the clock
const boolean zeromark[]  = {2,3,4,5};       // What pins are the zero switches connected to?
const int solenoid[]  = {6,7,9,8};           // What pins are the solenoids connected to?
const int seconds_pin = 10;                  // What pin are the second lamps connected to?

const int solenoid_ontime = 20;              // How long should the solenoid be active?
const int solenoid_offtime = 100;            // How long should the solenoid be inactive?

int hours_now;                               // Variable to hold the current hours read out from the RTC
int minutes_now;                             // Variable to hold the current minutes read out from the RTC
int seconds_now;                             // Variable to hold the current seconds read out from the RTC
int oldminutes;                              // Variable for when the digits were last updated


int hours_tens;                              // Variable for the breakdown of the current hours      H
int hours_ones;                              // Variable for the breakdown of the current hours      H
int minutes_tens;                            // Variable for the breakdown of the current minutes    M
int minutes_ones;                            // Variable for the breakdown of the current minutes    M

int digit0;                                  // Variable for holding what the digits are acctually showing, hours tens
int digit1;                                  // Variable for holding what the digits are acctually showing, hours ones
int digit2;                                  // Variable for holding what the digits are acctually showing, minutes tens
int digit3;                                  // Variable for holding what the digits are acctually showing, minutes ones


void setup() { 
  Serial.begin(57600);                                     // Serial is not needed, but a nice way to debug
  Wire.begin();
  RTC.begin();
  
  if (! RTC.isrunning()) {
    Serial.println("RTC is NOT running!");
    // following line sets the RTC to the date & time this sketch was compiled
    //RTC.adjust(DateTime(__DATE__, __TIME__));
  }
  
  pinMode(10, OUTPUT);                                      // Set up the seconds pin
  
  for(int i=0; i<digits; i++){
    pinMode(zeromark[i], INPUT_PULLUP);                     // Set up the rest of the input pins, with internal pull up
  }
  for(int i=0; i<digits; i++){
    pinMode(solenoid[i], OUTPUT);                           // Set up all the output pins
  }  
  
  for(int i=0; i<digits; i++){                             // Repeat for every digit, one at a time
	while (digitalRead(zeromark[i]) == HIGH){          // If digit is not 0, pulse the solenoid until it reaches 0
          Serial.print("Digit is not 0. Pulsing solenoid ");
          Serial.println(i);
	  digitalWrite(solenoid[i],HIGH);
          delay(solenoid_ontime);
          digitalWrite(solenoid[i],LOW);
          delay(solenoid_offtime);
	}	
  }

// Now we have a known state, where all digits show 0
// Now we have to update the digits with the correct time	
  DateTime now = RTC.now();                         // Get the time
  Serial.print(now.year(), DEC);
    Serial.print('/');
    Serial.print(now.month(), DEC);
    Serial.print('/');
    Serial.print(now.day(), DEC);
    Serial.print(' ');
    Serial.print(now.hour(), DEC);
    Serial.print(':');
    Serial.print(now.minute(), DEC);
    Serial.print(':');
    Serial.print(now.second(), DEC);
    Serial.println();
  hours_now = now.hour();                           // Put the current hours into hours_now
  minutes_now = now.minute();                       // Put the current minutes into minutes_now
  
  hours_tens = hours_now / 10;                      // Divide by 10 to get the first digit
  hours_ones = hours_now % 10;                      // Modulo to get the last digit
  minutes_tens = minutes_now / 10;                  // And the same for the minutes
  minutes_ones = minutes_now % 10;
  
  pulsesolenoid(0,hours_tens);                      // Pulse the solenoids in order, wth the amount of pulses set from the clock
  pulsesolenoid(1,hours_ones);
  pulsesolenoid(2,minutes_tens);
  pulsesolenoid(3,minutes_ones);
  
  digit0 = hours_tens;                              // Update the digit variables with what they are acctually showing
  digit1 = hours_ones;
  digit2 = minutes_tens;
  digit3 = minutes_ones;
  
  
  
  oldminutes = minutes_now;                         // Set oldminutes to when we last updated the clock
  delay(1000);                                      // Small delay just to separate the setup from the main loop
  }

void loop() {
    DateTime now = RTC.now();                       // Get the time
    hours_now = now.hour();                         // Get the hours
    minutes_now = now.minute();                     // Get the minutes
    seconds_now = now.second();                     // Get the seconds
    
    hours_tens = hours_now / 10;                    // Divide by 10 to get the first digit
    hours_ones = hours_now % 10;                    // Modulo to get the last digit
    minutes_tens = minutes_now / 10;                // And the same for the minutes
    minutes_ones = minutes_now % 10;

    if(minutes_now != oldminutes){                  // Check if it's time to advance the minutes.  
      advance();
      oldminutes = minutes_now;
    }
    
    if ( (seconds_now % 2) == 0) {                  // If seconds are an odd number, turn on the lamps...
      digitalWrite(seconds_pin, HIGH);
    }
    else{                                           // ... otherwise, turn them off
      digitalWrite(seconds_pin, LOW);
    }    
}




void pulsesolenoid(int solenoid_number, int times){
  Serial.print("Pulsing solenoid ");
  Serial.print(solenoid_number);
  Serial.print(" ");
  Serial.print(times);
  Serial.println(" times.");

  for (int i=0; i<times; i++){
	  digitalWrite(solenoid[solenoid_number],HIGH);
          delay(solenoid_ontime);
          digitalWrite(solenoid[solenoid_number],LOW);
          delay(solenoid_offtime);
  }
}


void advance(){
  Serial.println("Advancing time one minute");
  if(digit3 == 9){                                // If last digit is 9, we need to advance both ones and tens reel by one...
    if(digit2 == 5){                              // ...except if the minutes tens reel shows 5 (XX:59), then we need to pulse hours ones once, minutes tens five times, and minutes ones once.
      if(digit1 == 9){                            // ...and except if hours ones reel shows 9, then pulse hours tens once, hours ones once, minutes tens five times, minutes ones once.
        pulsesolenoid(0,1);
        pulsesolenoid(1,1);
        pulsesolenoid(2,5);
        pulsesolenoid(3,1);
      }
      else if(digit0 == 2 && digit1 == 3){        // ...and if the time is 23:59 then we need to andvance all the reels by 8, 7, 5 and 1. (This will make a lot of noise, and take some time)   
        pulsesolenoid(0,8);
        pulsesolenoid(1,7);
        pulsesolenoid(2,5);
        pulsesolenoid(3,1);
      }
      else{      
      pulsesolenoid(1,1);
      pulsesolenoid(2,5);
      pulsesolenoid(3,1);
      }
    }
    else{
      pulsesolenoid(2,1);
      pulsesolenoid(3,1);
    }
  }
  else{
    pulsesolenoid(3,1);
  }
  
  digit0 = hours_tens;                           // Update the time shown on the reels for the next time it's time to advance.
  digit1 = hours_ones;
  digit2 = minutes_tens;
  digit3 = minutes_ones;
  Serial.print("Time shown is now: ");
  Serial.print(digit0);
  Serial.print(digit1);
  Serial.print(":");
  Serial.print(digit2);
  Serial.println(digit3);
}