Svenska ElektronikForumet

Kod: Markera allt

DEFINE OSC 20				'Define OSC (20MHz)

' - - - Pins - - - 
magnet VAR PORTB.3			'Toggle electromagnet (hover function) 1= enable
Button0 VAR PORTB.4			'Button. 0 = active

' - - - Variables - - -
adc VAR BYTE			'ADC result
temp VAR BYTE			'temp byte, calculator
center VAR BYTE			'hover centrum
edge VAR BYTE			'hover edge

' - - - Initiate ports and values - - - 

'ADC config
ADCON0 = %10000001	'Initiate A/D-converter on channel 0 (AN0)
ADCON1 = %00001110	'F(osc)/32 clock source -  AN0 on (rest of portA is digital) -  left justified result
TRISA.0 = 1			'PortA.0 = input

'PWM config
TRISC.2 = 0			'PortC.2 output (PWM1)
CCP1CON = %00001100	'Mode select = PWM1 on
T2CON = %00000100	'Timer2 ON + 1:1 prescale
PR2 = 255			'~19,53 kHz @ 20MHz OSC, 10 bit resolution

'Other I/O-config
Input button0		'Button to set hover centrum

Read 0,edge		'Hallsensor edge value (from memory)
center = edge / 2

High magnet			'Turn on electromagnet


' - - - - - Main Loop - - - - - 
main_loop:

'Start on A/D-conversion to fetch at end of program loop
ADCON0.2 = 1		'Start A/D-conversion

'Set hover centrum (if button is pressed)
IF Button0 = 0 Then
	edge = adc + 1
	Write 0,edge
	center = edge / 2
EndIF

IF adc > center Then		'If magnet is too far away, pull it closer by increasing PWM
	temp = adc - center		'Difference
	IF temp < 32 Then		'Prevent rollover
		CCPR1L = 128 + (temp * temp / 8)	'Add sensor value to center
		High magnet			'Turn on electromagnet (if not on already)
	Else 
		Input magnet		'Turn off electromagnet (energy save). Magnet is too far away anyway
	EndIF
EndIF

IF adc < center Then		'If magnet is too close, push it away by decreasing PWM
	High magnet				'Turn on electromagnet (if not on already)
	temp = center - adc		'Difference
	IF temp < 64 Then		'Prevent rollover	
		CCPR1L = 127 - (2 * temp)	'Subtract sensor value from center
	Else 
		CCPR1L = 0			'If difference is too big, set PWM to zero (full push)
	EndIF
EndIF

IF adc = center Then		'Perefct match
	High magnet				'Turn on electromagnet (if not on already)
	CCPR1L = 128				'Neutral PWM (no push, no pull)
EndIF


'read_ADC:

adc = ADRESH		'Save ADC result

GoTo main_loop	'Loop forever

End